Aspect4Delphi下載Aspect4Delphi源代碼下載

Aspect4Delphi

Delphi源碼

1.0.4

下載

Delphi的方面

該方面4Delphi由一個庫組成，該庫可以在Delphi中使用面向方面的編程概念（AOP）。

關於項目

AOP是一種編程範式，旨在通過允許進行橫切問題的分離來增加模塊化。它通過在不修改代碼本身的情況下向現有代碼添加其他行為來做到這一點。相反，我們可以單獨聲明此新代碼和這些新行為。

Factions4Delphi幫助我們實施了這些橫切問題。

建議類型

在建議之前：在聯接點之前執行的建議，但沒有能力阻止執行流程到聯接點（除非引發異常）。
經過建議：聯合點後要執行的建議正常完成：例如，如果方法返回而不拋出異常而返回。
異常建議：如果方法通過拋出異常出口，則將執行建議。

建立

Delphi社區版 - 使用的IDE

入門

要啟動並運行本地副本，請遵循以下簡單步驟。

先決條件

要使用此庫，需要更新版本的Delphi IDE（XE或更高）。

安裝

克隆倉庫

 git clone https://github.com/ezequieljuliano/Aspect4Delphi.git

添加IDE或項目的“搜索路徑”以下目錄：

 Aspect4Delphisrc

用法

為了提供項目中的方面範式，您需要的是4Delphi：

實現點列屬性。
實施代表您方面的類。
在上下文中註冊您的cointcut屬性及其方麵類。
將您的類方法設置為虛擬。
通過各個方面寫下您的方法。

樣本

為了說明用法，讓我們看一下管理應用程序日誌的解決方案。

實現點cut屬性（最好是從aptiveattribute繼承）：

 interface

uses

  Aspect.Core;

type

  LoggingAttribute = class(AspectAttribute)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

implementation

end.

實現代表您的方面的類並包含建議方法（您必須實現ISPECT接口）：

 interface

uses

  System.SysUtils,
  System.Rtti,
  Aspect,
  Aspect.Core,
  Logging.Attribute,
  App.Context;

type

  ELoggingAspectException = class(Exception)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

  TLoggingAspect = class(TAspectObject, IAspect)
  private
    { private declarations }
  protected
    procedure OnBefore(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      out invoke: Boolean;
      out result: TValue
      ); override;

    procedure OnAfter(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      var result: TValue
      ); override;

    procedure OnException(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      out raiseException: Boolean;
      theException: Exception;
      out result: TValue
      ); override;
  public
    { public declarations }
  end;

implementation

{ TLoggingAspect }

procedure TLoggingAspect.OnAfter(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; var result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('After the execution of ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name
	  );
      Break;
    end;
end;

procedure TLoggingAspect.OnBefore(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; out invoke: Boolean; out result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('Before the execution of ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name
	  );
      Break;
    end;
end;

procedure TLoggingAspect.OnException(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; out raiseException: Boolean;
  theException: Exception; out result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('Exception in executing ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name + ' - ' + 
		theException.Message
	  );
      Break;
    end;
end;

end.

在上下文中註冊您的cointcut屬性及其方麵類（最好將此上下文保留在Singleton實例中）：

 interface

uses

  Logging.Aspect;
  Aspect.Context;  
  
function AspectContext: IAspectContext;

implementation

var

  AspectContextInstance: IAspectContext = nil;
  
function AspectContext: IAspectContext;
begin
  if (AspectContextInstance = nil) then
  begin
    AspectContextInstance := TAspectContext.Create;
    AspectContextInstance.RegisterAspect(TLoggingAspect.Create);
  end;
  Result := AspectContextInstance;
end;

end.

在您的業務規則類中，使用屬性來定義您的加入點。您可以使用構造函數和驅動器在織布工中添加類。

 interface

uses

  System.SysUtils,
  Logging.Attribute,
  App.Context;

type

  EWhatsAppMessageException = class(Exception)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

  TWhatsAppMessage = class
  private
    { private declarations }
  protected
    { protected declarations }
  public
    constructor Create;
    destructor Destroy; override;

    [Logging]
    procedure Send; virtual;
  end;

implementation

{ TWhatsAppMessage }

constructor TWhatsAppMessage.Create;
begin
  inherited Create;
  AspectContext.Weaver.Proxify(Self);
end;

destructor TWhatsAppMessage.Destroy;
begin
  AspectContext.Weaver.Unproxify(Self);
  inherited Destroy;
end;

procedure TWhatsAppMessage.Send;
begin
  //Execution of send.
end;