Aspect4Delphi

Delphi的方面

该方面4Delphi由一个库组成，该库可以在Delphi中使用面向方面的编程概念（AOP）。

关于项目

AOP是一种编程范式，旨在通过允许进行横切问题的分离来增加模块化。它通过在不修改代码本身的情况下向现有代码添加其他行为来做到这一点。相反，我们可以单独声明此新代码和这些新行为。

Factions4Delphi帮助我们实施了这些横切问题。

建议类型

• 在建议之前：在联接点之前执行的建议，但没有能力阻止执行流程到联接点（除非引发异常）。
• 经过建议：联合点后要执行的建议正常完成：例如，如果方法返回而不抛出异常而返回。
• 异常建议：如果方法通过抛出异常出口，则将执行建议。

建立

• Delphi社区版 - 使用的IDE

入门

要启动并运行本地副本，请遵循以下简单步骤。

先决条件

要使用此库，需要更新版本的Delphi IDE（XE或更高）。

安装

克隆仓库

 git clone https://github.com/ezequieljuliano/Aspect4Delphi.git

添加IDE或项目的“搜索路径”以下目录：

 Aspect4Delphisrc

用法

为了提供项目中的方面范式，您需要的是4Delphi：

• 实现点列属性。
• 实施代表您方面的类。
• 在上下文中注册您的cointcut属性及其方面类。
• 将您的类方法设置为虚拟。
• 通过各个方面写下您的方法。

样本

为了说明用法，让我们看一下管理应用程序日志的解决方案。

实现点cut属性（最好是从aptiveattribute继承）：

 interface

uses

  Aspect.Core;

type

  LoggingAttribute = class(AspectAttribute)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

implementation

end.

实现代表您的方面的类并包含建议方法（您必须实现ISPECT接口）：

 interface

uses

  System.SysUtils,
  System.Rtti,
  Aspect,
  Aspect.Core,
  Logging.Attribute,
  App.Context;

type

  ELoggingAspectException = class(Exception)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

  TLoggingAspect = class(TAspectObject, IAspect)
  private
    { private declarations }
  protected
    procedure OnBefore(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      out invoke: Boolean;
      out result: TValue
      ); override;

    procedure OnAfter(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      var result: TValue
      ); override;

    procedure OnException(
      instance: TObject;
      method: TRttiMethod;
      const args: TArray<TValue>;
      out raiseException: Boolean;
      theException: Exception;
      out result: TValue
      ); override;
  public
    { public declarations }
  end;

implementation

{ TLoggingAspect }

procedure TLoggingAspect.OnAfter(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; var result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('After the execution of ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name
	  );
      Break;
    end;
end;

procedure TLoggingAspect.OnBefore(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; out invoke: Boolean; out result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('Before the execution of ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name
	  );
      Break;
    end;
end;

procedure TLoggingAspect.OnException(instance: TObject; method: TRttiMethod;
  const args: TArray<TValue>; out raiseException: Boolean;
  theException: Exception; out result: TValue);
var
  attribute: TCustomAttribute;
begin
  inherited;
  for attribute in method.GetAttributes do
    if attribute is LoggingAttribute then
    begin
      LoggingFile.Add('Exception in executing ' + 
		instance.QualifiedClassName + ' - ' + 
		method.Name + ' - ' + 
		theException.Message
	  );
      Break;
    end;
end;

end.

在上下文中注册您的cointcut属性及其方面类（最好将此上下文保留在Singleton实例中）：

 interface

uses

  Logging.Aspect;
  Aspect.Context;  
  
function AspectContext: IAspectContext;

implementation

var

  AspectContextInstance: IAspectContext = nil;
  
function AspectContext: IAspectContext;
begin
  if (AspectContextInstance = nil) then
  begin
    AspectContextInstance := TAspectContext.Create;
    AspectContextInstance.RegisterAspect(TLoggingAspect.Create);
  end;
  Result := AspectContextInstance;
end;

end.

在您的业务规则类中，使用属性来定义您的加入点。您可以使用构造函数和驱动器在织布工中添加类。

 interface

uses

  System.SysUtils,
  Logging.Attribute,
  App.Context;

type

  EWhatsAppMessageException = class(Exception)
  private
    { private declarations }
  protected
    { protected declarations }
  public
    { public declarations }
  end;

  TWhatsAppMessage = class
  private
    { private declarations }
  protected
    { protected declarations }
  public
    constructor Create;
    destructor Destroy; override;

    [Logging]
    procedure Send; virtual;
  end;

implementation

{ TWhatsAppMessage }

constructor TWhatsAppMessage.Create;
begin
  inherited Create;
  AspectContext.Weaver.Proxify(Self);
end;

destructor TWhatsAppMessage.Destroy;
begin
  AspectContext.Weaver.Unproxify(Self);
  inherited Destroy;
end;

procedure TWhatsAppMessage.Send;
begin
  //Execution of send.
end;

路线图

有关拟议功能（以及已知问题）的列表，请参见开放问题。

贡献

贡献是使开源社区成为学习，启发和创造的惊人场所的原因。您所做的任何贡献都非常感谢。

1. 分叉项目
2. 创建您的功能分支（ git checkout -b feature/AmazingFeature ）
3. 提交您的更改（ git commit -m 'Add some AmazingFeature' ）
4. 推到分支机构（ git push origin feature/AmazingFeature ）
5. 打开拉请请求

执照

根据Apache许可证分发。有关更多信息，请参见LICENSE 。

接触

与我们联系使用以下选项：

• 电子邮件：[email protected]
• Twitter：@ezequieljuliano
• LinkedIn：Ezequiel-Juliano-Müller

项目链接

https://github.com/ezequieljuliano/aspect4delphi