FileSystemObject物件被用來存取伺服器上的檔案系統。這個物件能夠處理檔案、資料夾和目錄路徑。用它來檢索文件系統資訊也是可能的。
下面的程式碼建立了一個文字文件，並寫入了一些文字：
<%
dim fs,fname
set fs=Server.CreateObject("Scripting.FileSystemObject")
set fname=fs.CreateTextFile("c:/test.txt",true)
fname.WriteLine("Hello World!")
fname.Close
set fname=nothing
set fs=nothing
%>
FileSystemObject物件的屬性與方法如下：
一、屬性
Drives：傳回電腦上關於所有Drive物件的集。
文法:
[drivecoll=]FileSystemObject.Drives
二、方法
Bulidpath：為已存在的路徑增加一個名字。
CopyFile：從一處複製一個或多個檔案到另一處。
CopyFolder：從一處複製一個或多個資料夾到另一處。
CreateFolder：建立一個新的資料夾。
CreateTextFile：建立一個文字檔案並傳回一個TextStream物件用來讀寫所建立的文字檔案。
DeleteFile：刪除一個或多個指定的檔案。
DeleteFolder：刪除一個或多個指定的資料夾。
DriveExists：檢查指定的磁碟機是否存在。
FileExists：檢查指定的檔案是否存在。
FolderExists：檢查指定的資料夾是否存在。
GetAbsolutePathName：傳回指定路徑的完整路徑。
GetBaseName：傳回指定檔案或資料夾的基本名稱。
GetDrive：傳回指定路徑的在磁碟機的對應Drive物件。
GetDriveName：傳回指定路徑的磁碟機名稱。
GetExtensionName：傳回指定路徑中最後部分的檔案副檔名。
GetFile：傳回一個關於指定路徑的檔案物件。
GetFileName：傳回指定路徑中最後部分的檔案名稱或資料夾名稱。
GetFolder：傳回一個關於指定路徑的資料夾物件。
GetParentFolderName：傳回指定路徑中最後部分的父資料夾名稱。
GetSpecialFolder：傳回Windows某個專門資料夾的路徑。
GetTempName：傳回一個隨機產生的暫存檔案或資料夾。
MoveFile：將一個或多個檔案從一個地方移動到另一個地方。
MoveFolder：將一個或多個檔案從一個地方移動到另一個地方。
OpenTextFile：開啟一個檔案並傳回一個TextStream物件用來讀寫所開啟的檔案。
BuildPath方法
BuildPath方法為已存在的路徑增加一個名字。
一、文法
[newpath=]FileSystemObject.BuildPath(path,name)
參數說明：
path：必須的。路徑。
name：所要增加的名字。
二、例子
<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.BuildPath("c:/mydocuments","test")
response.write(path)
set fs=nothing
%>
輸出:
c:/mydocuments/test
CopyFile方法
CopyFile方法從一處複製一個或多個檔案到另一處。
一、文法
FileSystemObject.CopyFile source,destination[,overwrite]
參數說明：
source：必須的。所要複製的文件。
destination：必須的。複製到的目的地。
overwrite：可選的。是個布林值，它指出是否覆蓋已存在的檔案。 True表示覆蓋，False表示不覆蓋。預設為True 。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFile "c:/mydocuments/web/*.htm","c:/webpages/"
set fs=nothing
%>
CopyFolder方法
CopyFolder方法一處複製一個或多個檔案到另一處。
一、文法
FileSystemObject.CopyFolder source,destination[,overwrite]
參數說明：
source：必須的。所要複製的資料夾。
destination：必須的。複製到的目的地。
overwrite：可選的。是個布林值，它指出是否覆蓋已存在的檔案。 True表示覆蓋，False表示不覆蓋。預設為True 。
二、例子
<%
'copy all the folders in c:/mydocuments/web
'to the folder c:/webpages
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFolder "c:/mydocuments/web/*","c:/webpages/"
set fs=nothing
%>
<%
'copy only the folder test from c:/mydocuments/web
'to the folder c:/webpages
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFolder "c:/mydocuments/web/test","c:/webpages/"
set fs=nothing
%>
CreateFolder方法
CreateFolder方法建立一個新的資料夾。
一、文法
FileSystemObject.CreateFolder(name)
參數說明：
name：必須的。要建立的資料夾的名字。
二、例子
<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.CreateFolder("c:/asp")
set f=nothing
set fs=nothing
%>
CreateTextFile方法
CreateTextFile方法在目前資料夾下建立一個新的文字文件，並傳回一個TextStream物件用來讀寫這個新的文件。
一、文法
FileSystemObject.CreateTextFile(filename[,overwrite[,unicode]])
FolderObject.CreateTextFile(filename[,overwrite[,unicode]])
參數說明：
filename：必須的。所要創建的文件的名字。
overwrite：可選的。是一布林值，以指出是否覆蓋已存在的檔案。 True表示覆蓋，False表示不覆蓋。預設為True 。
unicode：可選的。為一布林值，指出所建立的檔案是Unicode檔案還是ASCII檔案。 True為Unicode文件，False為ASCII文件。預設是False。
二、例子
FileSystemObject的例子：
<%
dim fs,tfile
set fs=Server.CreateObject("Scripting.FileSystemObject")
set tfile=fs.CreateTextFile("c:/somefile.txt")
tfile.WriteLine("Hello World!")
tfile.close
set tfile=nothing
set fs=nothing
%>
Folder物件的例子：
<%
dim fs,fo,tfile
Set fs=Server.CreateObject("Scripting.FileSystemObject")
Set fo=fs.GetFolder("c:/test")
Set tfile=fo.CreateTextFile("test.txt",false)
tfile.WriteLine("Hello World!")
tfile.Close
set tfile=nothing
set fo=nothing
set fs=nothing
%>
DeleteFile方法
DeleteFile方法刪除一個或多個指定的檔案。
注意：如果試圖刪除不存在的檔案將會發生錯誤。
一、文法
FileSystemObject.DeleteFile(filename[,force])
參數說明：
filename：必須的。所要刪除的檔案的名稱。
force：可選的。一個布林值，以表示是否刪除只讀檔案。 True為是，False為否。預設是False。
二、例子
<%
dim fs
Set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CreateTextFile("c:/test.txt",True)
if fs.FileExists("c:/test.txt") then
fs.DeleteFile("c:/test.txt")
end if
set fs=nothing
%>
DeleteFolder方法
DeleteFolder方法DeleteFile方法刪除一個或多個指定的資料夾。
注意：如果試圖刪除不存在的資料夾將會發生錯誤。
一、文法
FileSystemObject.DeleteFolder(foldername[,force])
參數說明：
foldername：必須的。所要刪除的檔案的名稱。
force：可選的。一個布林值，以表示是否刪除只讀資料夾。 True為是，False為否。預設是False。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FolderExists("c:/temp") then
fs.DeleteFolder("c:/temp")
end if
set fs=nothing
%>
DriveExists方法
DriveExists方法傳回布林值表示指定的磁碟機是否存在。 True為存在，False為否。
一、文法
FileSystemObject.DriveExists(drive)
參數說明：
drive：必須的。一個驅動器符或一完整的路徑描述。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.DriveExists("c:")=true then
response.write("Drive c: exists!")
else
response.write("Drive c: does not exist.")
end If
set fs=nothing
%>
FileExists方法
FileExists方法傳回一個布林值表示指定的檔案是否存在。 True為存在，False為否。
一、文法
FileSystemObject.FileExists(filename)
參數說明：
filename：必須的。所要檢查的文件的名字。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FileExists("c:/asp/introduction.asp")=true then
response.write("File c:/asp/introduction.asp exists!")
else
response.write("File c:/asp/introduction.asp does not exist!")
end if
set fs=nothing
%>
FolderExists方法
FolderExists方法傳回一個布林值表示指定的資料夾是否存在。 True為存在，False為否。
一、文法
FileSystemObject.FolderExists(foldername)
參數說明：
foldername：必須的。所要檢查的資料夾的名字。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FolderExists("c:/asp")=true then
response.write("Folder c:/asp exists!")
else
response.write("Folder c:/asp does not exist!")
end if
set fs=nothing
%>
GetAbsolutePathName方法
GetAbsolutePathName方法傳回關於指定路徑的完整路徑（將指定路徑轉換為絕對路徑）。
一、文法
FileSystemObject.GetAbsolutePathName(path)
參數說明：
path：必須的。要轉換為絕對路徑的路徑。
二、例子
假設目前目錄是c:/temp/test:
例1
<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("c:")
response.write(path)
%>
輸出:
c:/temp/test
例2
<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("mydoc.txt")
response.write(path)
%>
輸出:
c:/temp/test/mydoc.txt
例3
<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("private/mydoc.txt")
response.write(path)
%>
輸出:
c:/temp/test/private/mydoc.txt
GetBaseName方法
GetBaseName方法傳回指定路徑中檔案或資料夾的基本名稱。
一、文法
FileSystemObject.GetBaseName(path)
參數說明：
path：必須的。文件或資料夾的路徑。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
Response.Write(fs.GetBaseName("c:/winnt/cursors/3dgarro.cur"))
set fs=nothing
%>
輸出:
3dgarro
GetDrive方法
GetDrive方法傳回一個由drivespec參數指定的Drive物件。
一、文法
FileSystemObject.GetDrive(drivespec)
參數說明：
drivespec：必須的。可以是一個磁碟機符號©，或後面跟著冒號的磁碟機符號(c:)，或後面跟著冒號和路徑分隔符號的磁碟機符號(c:/)，或網路共用說明(//computer2/share1)。
二、例子
<%
dim fs,d
set fs=Server.CreateObject("Scripting.FileSystemObject")
set d=fs.GetDrive("c:/")
set fs=nothing
%>
GetDriveName方法
GetDriveName方法傳回一個包含指定路徑的磁碟機的名字的字串。
一、文法
FileSystemObject.GetDriveName(path)
參數說明：
path：必須的。指定的路徑。
二、例子
<%
dim fs,dname
set fs=Server.CreateObject("Scripting.FileSystemObject")
dname=fs.GetDriveName("c:/test/test.htm")
Response.Write(dname)
set fs=nothing
%>
輸出:
c:
GetExtensionName方法
GetExtensionName方法傳回一個包含指定路徑中最後部分的檔案的檔案副檔名的字串。
一、文法
FileSystemObject.GetExtensionName(path)
參數說明：
path：必須的。指定的路徑。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
Response.Write(fs.GetExtensionName("c:/test/test.htm"))
set fs=nothing
%>
輸出:
htm
GetFile方法
GetFile方法傳回關於指定路徑的一個File物件。
一、文法
FileSystemObject.GetFile(path)
參數說明：
path：必須的。關於特定文件的路徑。
二、例子
<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.GetFile("c:/test/test.htm")
Response.Write("The file was last modified on: ")
Response.Write(f.DateLastModified)
set f=nothing
set fs=nothing
%>
輸出:
The file was last modified on 01/01/20 4:23:56 AM
GetFileName方法
GetFileName方法傳回一個包含指定路徑中最後部分的檔案或資料夾的名字的字串。
一、文法
FileSystemObject.GetFileName(path)
參數說明：
path：必須的。關於特定文件或資料夾的路徑。
二、例子
<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.getfilename("c:/test/test.htm")
response.write(p)
set fs=nothing
%>
輸出:
test.htm
<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.getfilename("c:/test/")
response.write(p)
set fs=nothing
%>
輸出:
test
GetFolder方法
GetFolder方法傳回關於指定路徑的一個Folder物件。
一、文法
FileSystemObject.GetFolder(path)
參數說明：
path：必須的。關於一特定資料夾的路徑。
二、例子
<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.GetFolder("c:/test/")
Response.Write("The folder was last modified on: ")
Response.Write(f.DateLastModified)
set f=nothing
set fs=nothing
%>
輸出:
The folder was last modified on 01/01/20 4:23:56 AM
GetParentFolderName方法
GetParentFolderName方法傳回指定路徑中最後部分的父資料夾的名字。
一、文法
FileSystemObject.GetParentFolderName(path)
參數說明：
path：必須的。要返回其父資料夾名字的檔案或資料夾的路徑。
二、例子
<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.GetParentFolderName("c:/winnt/cursors/3dgarro.cur")
Response.Write(p)
set fs=nothing
%>
輸出:
c:/winnt/cursors
GetSpecialFolder方法
GetSpecialFolder方法傳回關於某Windows特定資料夾的路徑。
一、文法
FileSystemObject.GetSpecialFolder(foldername)
參數說明：
foldername：必須的。
foldername取值說明：
0=WindowsFolder（包含被windows作業系統安裝的檔案）；
1=SystemFolder（包含庫、字體和裝置驅動程式）
2=TemporaryFolder（用來儲存臨時檔案）
二、例子
<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
set p=fs.GetSpecialFolder(1)
Response.Write(p)
set p=nothing
set fs=nothing
%>
輸出:
C:/WINNT/system32
GetTempName方法
GetTempName方法傳回一個隨機產生的暫存檔案或資料夾。
一、文法
FileSystemObject.GetTempName
二、例子
<%
dim fs,tfolder,tname, tfile
Set fs=Server.CreateObject("Scripting.FileSystemObject")
Set tfolder=fs.GetSpecialFolder(2)
tname=fs.GetTempName
Set tfile=tfolder.CreateTextFile(tname)
Response.write (tfile)
%>
輸出:
trb2007.tmp
MoveFile方法
MoveFile方法把一個或多個檔案從一處移動到另一處。
一、文法
FileSystemObject.MoveFile source,destination
參數說明：
source：必須的。要被移動的文件的路徑。
destination：必須的。所要移動到的位置。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.MoveFile "c:/web/*.gif","c:/images/"
set fs=nothing
%>
MoveFolder方法
MoveFolder方法把一個或多個資料夾從一處移動到另一處。
一、文法
FileSystemObject.MoveFolder source,destination
參數說明：
source：必須的。要被移動的資料夾的路徑。
destination：必須的。所要移動到的位置。
二、例子
<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.MoveFolder "c:/test/web/","c:/windows/"
set fs=nothing
%>
OpenTextFile方法
OpenTextFile方法開啟一個指定的檔案並傳回一個TextStream物件以用來存取這個檔案。
一、文法
FileSystemObject.OpenTextFile(fname,mode,create,format)
參數說明：
fname：必須的。要打開的文件的名字。
mode：可選的。以什麼方式打開。 1=ForReading（以唯讀方式開啟），2=ForWriting （以寫入方式開啟），8=ForAppending（以新增方式打開，寫入的內容將會新增至檔案結尾）。
create：可選的。設定如果所開啟的檔案不存在是否建立該檔案。 True為是，False為否。預設是False。
format：可選的。文件的格式。 0=TristateFalse（以ASCII格式打開，這是預設的），-1=TristateTrue（以Unicode格式開啟），-2=TristateUseDefault （以系統預設方式開啟）
二、例子
<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.OpenTextFile(Server.MapPath("testread.txt"),8,true)
f.WriteLine("This text will be added to the end of file")
f.Close
set f=Nothing
set fs=Nothing
%>
Property
屬性Description
描述
Attributes
Sets or returns the attributes of a specified file
設定或傳回指定檔案的屬性
DateCreated
Returns the date and time when a specified file was created
傳回指定檔案建立的日期和時間
DateLastAccessed
Returns the date and time when a specified file was last accessed
傳回指定檔案最後被存取的日期和時間
DateLastModified
Returns the date and time when a specified file was last modified
傳回指定檔案最後被修改的日期和時間
Drive
Returns the drive letter of the drive where a specified file or folder resides
傳回指定檔案或資料夾所處的盤符的磁碟符號
Name
Sets or returns the name of a specified file
設定或傳回指定檔案的名字
ParentFolder
Returns the folder object for the parent of the specified file
傳回指定檔案的父資料夾
Path
Returns the path for a specified file
傳回一個指定檔案的路徑
ShortName
Returns the short name of a specified file (the 8.3 naming convention)
傳回一個指定檔案的短名(根據8.3 命名規則)
ShortPath
Returns the short path of a specified file (the 8.3 naming convention)
傳回一個指定檔案的短路徑(根據8.3 命名規則)
Size
Returns the size, in bytes, of a specified file
傳回指定檔案所包含的位元組數
Type
Returns the type of a specified file
傳回指定文件的類型
Methods
方法
Method
方法Description
描述
Copy
Copies a specified file from one location to another
將本機上的檔案複製到異地機子上
Delete Deletes a specified file
刪除指定文件
Move
Moves a specified file from one location to another
將本機上的檔案移到異地機子上
OpenAsTextStream
Opens a specified file and returns a TextStream object to access the file
開啟指定檔案傳回一個TextStream對象
這篇文章就介紹到這裡了，建議繼續看下面的相關文章就行深入學習。