xdpw

XD Pascal для Windows

Посвящается моему отцу Михаилу Терешкову, который привил мне вкус к инженерии

Краткое содержание

XD Pascal-это небольшой встроенный компилятор самостоятельного самолета для диалекта языка Pascal. Любые комментарии, предложения или отчеты об ошибках оценены. Не стесняйтесь обращаться к автору на GitHub или по электронной почте [email protected]. Наслаждаться.

Функции

• Методы и интерфейсы в стиле
• Нативная генерация кода X86 (32 -битные исполнительные файлы Windows)
• Поддержка приложений консоли и графического интерфейса
• Внешний ассемблер или линкера не требуется
• Арифметика с плавающей точкой с использованием x87 FPU
• Интеграция с библиотекой разработки Game Raylib
• Интеграция с Geany IDE
• Источник компилятора для Delphi 6/7, Free Pascal и XD Pascal (Delphi 2009+ миграция проста)

Подробное описание

Использование

Введите командную строку:

 xdpw <file.pas>

Исходный файл должен быть указан с помощью его расширения (.pas).

Язык

XD Pascal похож на Delphi 6/7 и Free Pascal со следующими изменениями:

Улучшения

• Компилятор самостоятельно ведет себя
• Компилятор чрезвычайно компактен (~ 10000 линий) и может быть легко встроен в более крупные системы
• Поддерживаются методы и интерфейсы в стиле GO

Различия

• Строки-это массивы символов (стиль C), но индексируются из 1 для совместимости Pascal
• Тип Text эквивалентен file . Он может быть использован как для текста, так и для нетипированных файлов
• Вызовы методов и вызовы процедурных переменных требуют скобок даже для пустых списков параметров

Ограничения

• Нет классического (C ++/Delphi Style) объектно-ориентированное программирование
• Нет визуальных компонентов
• Единицы не могут быть скомпилированы отдельно
• Только оптимизация глазки
• Extended эквивалентен Double
• Нет High и Low функций для открытых массивов. Длина открытого массива должна быть явно передана в подпрограмму
• Метки операторов не могут быть численными

Формальная грамматика

 ProgramOrUnit = [("program" | "unit") Ident ";"] 
                ["interface"] [UsesClause] Block "." .
                
UsesClause = "uses" Ident {"," Ident} ";" .                

Block = { Declarations } (CompoundStatement | "end") .

Declarations = DeclarationSection ["implementation" DeclarationSection] .

DeclarationSection = LabelDeclarations |
                     ConstDeclarations | 
                     TypeDeclarations |
                     VarDeclarations |
                     ProcFuncDeclarations .
                     
Initializer = ConstExpression |
              StringLiteral |
              "(" Initializer {"," Initializer} ")" |
              "(" Ident ":" Initializer {";" Ident ":" Initializer} ")" |
              SetConstructor .                     
               
LabelDeclarations = "label" Ident {"," Ident} ";"               
             
ConstDeclarations = (UntypedConstDeclaration | TypedConstDeclaration)
               {";" (UntypedConstDeclaration | TypedConstDeclaration)} .

UntypedConstDeclaration = "const" Ident "=" ConstExpression .
                                 
TypedConstDeclaration = "const" Ident ":" Type "=" Initializer .

TypeDeclarations = "type" Ident "=" Type ";" {Ident "=" Type ";"} .

VarDeclarations = "var" IdentList ":" Type ["=" Initializer] ";" 
                       {IdentList ":" Type ["=" Initializer] ";"} .

ProcFuncDeclarations = ("procedure" | "function") Ident 
                       [Receiver] [FormalParams] [":" TypeIdent] 
                       [CallModifier] ";" [(Directive | Block) ";"] .

Receiver = "for" Ident ":" TypeIdent .

CallModifier = "stdcall" | "cdecl" .

Directive = "forward" | "external" ConstExpression .         

ActualParams = "(" [ (Expression | Designator) |
                {"," (Expression | Designator)} ] ")" .

FormalParams = "(" FormalParamList {";" FormalParamList} ")" .
              
FormalParamList = ["const" | "var"] IdentList [":" ["array" "of"] TypeIdent] 
                                              ["=" ConstExpression] .             

IdentList = Ident {"," Ident} .

Type = "(" Ident {"," Ident} ")" |
       "^" TypeIdent |
       ["packed"] "array" "[" Type {"," Type} "]" "of" Type |
       ["packed"] "record" Fields "end" |
       ["packed"] "interface" FixedFields "end" |
       ["packed"] "set" "of" Type |
       ["packed"] "string" [ "[" ConstExpression "]" ] |
       ["packed"] "file" ["of" Type] |
       ConstExpression ".." ConstExpression |
       ("procedure" | "function") [FormalParams] [":" TypeIdent] [CallModifier] |
       Ident .
       
Fields = FixedFields 
           ["case" [Ident ":"] Type "of" 
               ConstExpression {"," ConstExpression} ":" "(" Fields ")"
          {";" ConstExpression {"," ConstExpression} ":" "(" Fields ")"}] [";"] .       
       
FixedFields = IdentList ":" Type {";" IdentList ":" Type} .       
       
TypeIdent = "string" | "file" | Ident .       

Designator = BasicDesignator {Selector} .

BasicDesignator = Ident |
                  Ident [ActualParams] |
                  Ident "(" Expression ")" .

Selector = "^" | 
           "[" Expression {"," Expression} "]" | 
           "." Ident | 
           "(" ActualParams ")".

Statement = [Label ":"] [ (Designator | Ident) ":=" Expression | 
                          (Designator | Ident) [ActualParams] {Selector} |
                          CompoundStatement |
                          IfStatement |
                          CaseStatement |
                          WhileStatement |
                          RepeatStatement | 
                          ForStatement |
                          GotoStatement |
                          WithStatement ] .
                          
Label = Ident .                          

StatementList = Statement {";" Statement} .

CompoundStatement = "begin" StatementList "end" .

IfStatement = "if" Expression "then" Statement ["else" Statement] .

CaseStatement = "case" Expression "of" CaseElement {";" CaseElement} 
                    [";"] ["else" StatementList] [";"] "end" .
                    
WhileStatement = "while" Expression "do" Statement .

RepeatStatement = "repeat" StatementList "until" Expression .

ForStatement = "for" Ident ":=" Expression ("to" | "downto") Expression "do" Statement.

GotoStatement = "goto" Label .

WithStatement = "with" Designator {"," Designator} "do" Statement .                    
 
CaseElement = CaseLabel {"," CaseLabel} ":" Statement .

CaseLabel = ConstExpression [".." ConstExpression] .

ConstExpression = Expression .

Expression = SimpleExpression [("="|"<>"|"<"|"<="|">"|">="|"in") SimpleExpression] .

SimpleExpression = ["+"|"-"] Term {("+"|"-"|"or"|"xor") Term}.

Term = Factor {("*"|"/"|"div"|"mod"|"shl"|"shr"|"and") Factor}.

Factor = (Designator | Ident) [ActualParams] {Selector} |
         Designator |
         "@" Designator | 
         Number | 
         CharLiteral |
         StringLiteral |  
         "(" Expression ")" | 
         "not" Factor |
         SetConstructor |
         "nil" |
         Ident "(" Expression ")" {Selector} .
         
SetConstructor = "[" [Expression [".." Expression] 
                     {"," Expression [".." Expression]}] "]" .         

Ident = (Letter | "_") {Letter | "_" | Digit}.

Number = "$" HexDigit {HexDigit} | 
         Digit {Digit} ["." {Digit}] ["e" ["+" | "-"] Digit {Digit}] .

CharLiteral = "'" (Character | "'" "'") "'" | 
              "#" Number .

StringLiteral = "'" {Character | "'" "'"} "'".

Компилятор

Компилятор основан на рекурсивном анализаторе спуска. Он напрямую строит исполняемый файл Windows PE без использования внешнего ассемблера или линкера.

Директивы

• $APPTYPE - установить тип приложения. Примеры: {$APPTYPE GUI} , {$APPTYPE CONSOLE}
• $UNITPATH - установите дополнительный путь поиска модуля. Пример: {$UNITPATH ..units}

Оптимизация

Выполняются некоторые простые оптимизации глазки:

• Толкание/поп -элиминация
• FPU Push/POP Устранение
• Оптимизации локальной переменной нагрузки
• Оптимизация доступа к элементам массива
• Оптимизация доступа к полевым записям
• Оптимизация назначения
• Сравнение оптимизации
• Оптимизация тестирования состояния

Вставленные процедуры и функции

Следующие идентификаторы реализованы как часть компилятора. Их имена не являются зарезервированными словами и могут быть локально переопределены пользователем.

 procedure Inc ( var x: Integer);
procedure Dec ( var x: Integer);
procedure Read ([ var F: file ;] var x1 { ; var xi } );
procedure Write ([ var F: file ;] x1[:w[:d]] { ; xi[:w[:d]] } );
procedure ReadLn ([ var F: file ;] var x1 { ; var xi } );
procedure WriteLn ([ var F: file ;] x1[:w[:d]] { ; xi[:w[:d]] } );
procedure New ( var P: Pointer);
procedure Dispose ( var P: Pointer);
procedure Break ;
procedure Continue ;
procedure Exit ;
procedure Halt [( const error: Integer)];
function SizeOf ( var x | T): Integer;
function Ord (x: T): Integer;
function Chr (x: Integer): Char;
function Low ( var x: T | T): T;
function High ( var x: T | T): T;
function Pred (x: T): T;
function Succ (x: T): T;
function Round (x: Real): Integer;
function Abs (x: T): T;
function Sqr (x: T): T;
function Sin (x: Real): Real;  
function Cos (x: Real): Real;  
function Arctan (x: Real): Real;  
function Exp (x: Real): Real;
function Ln (x: Real): Real;
function SqRt (x: Real): Real;

Стандартная библиотека

Система

 function Timer : Integer;
procedure GetMem ( var P: Pointer; Size: Integer);
procedure FreeMem ( var P: Pointer);
procedure Randomize ;
function Random : Real;
procedure Assign ( var F: file ; const Name : string);
procedure Rewrite ( var F: file [; BlockSize: Integer]);
procedure Reset ( var F: file [; BlockSize: Integer]);
procedure Close ( var F: file );
procedure BlockRead ( var F: file ; var Buf; Len: Integer; var LenRead: Integer);
procedure BlockWrite ( var F: file ; var Buf; Len: Integer);
procedure Seek ( var F: file ; Pos: Integer);
function FileSize ( var F: file ): Integer;
function FilePos ( var F: file ): Integer;
function EOF ( var F: file ): Boolean;
function IOResult : Integer;
function Length ( const s: string): Integer;
procedure Move ( var Source; var Dest; Count: Integer);
function Copy ( const S: string; Index, Count: Integer): string;
procedure FillChar ( var Data; Count: Integer; Value : Char);
function ParamCount : Integer;
function ParamStr (Index: Integer): string;
procedure Val ( const s: string; var Number: Real; var Code: Integer);
procedure Str (Number: Real; var s: string[; DecPlaces: Integer]);
procedure IVal ( const s: string; var Number: Integer; var Code: Integer);
procedure IStr (Number: Integer; var s: string);
function UpCase (ch: Char): Char;

Sysutils Unit

 function IntToStr (n: Integer): string;
function StrToInt ( const s: string): Integer;
function FloatToStr (x: Real): string;
function FloatToStrF (x: Real; Format: TFloatFormat; Precision, Digits: Integer): string;
function StrToFloat ( const s: string): Real;
function StrToPChar ( const s: string): PChar;
function PCharToStr (p: PChar): string;
function StrToPWideChar ( const s: string): PWideChar;
function PWideCharToStr (p: PWideChar): string;

Образцы

• factor.pas - Демо.
• lineq.pas - Линейный решатель уравнений. Использует gauss.pas Unit. Требуется eq.txt , eqerr.txt или аналогичный файл данных
• life.pas - игра жизни
• sort.pas - демо сортировка массива
• fft.pas - быстрое преобразование Фурье
• inserr.pas - Демонстрация ошибок инерционной навигационной системы. Использует единицу kalman.pas
• list.pas - Демонстрация операций с связанными списками
• map.pas - гетерогенные операции списка и демонстрация функции карты. Демонстрирует методы и интерфейсы XD Pascal
• gui.pas - Демо -версия GUI. Использует windows.pas UNIT
• raytracer.pas - raytracer demo. Демонстрирует методы и интерфейсы XD Pascal. Эквивалент raytracer.go

Известные проблемы

Известно, что антивирус Defender Windows дает ложные положительные результаты по некоторым программам, скомпилированным с XD Pascal.